雖然建議在每個Perl腳本和模塊中開啟警告，可是你又不想用戶看到Perl發(fā)出的警告。
一方面你想在代碼前面使用use warnings作為你的安全網(wǎng)，另一方面，通常警告會出現(xiàn)在屏幕上。多數(shù)情況下，客戶不知道如何處理這些警告。如果幸運(yùn)的話這些警告僅僅讓客戶驚訝一下，當(dāng)然，不幸的是他們嘗試著去修復(fù)它們... （這里說的不是Perl程序員。）
第三方面，你或許想要保存這些警告供之后分析。
此外，在很多地方還有很多Perl腳本和應(yīng)用程序沒有使用use warnings也沒有在#!行中使用-w。加上了use warnings就可能會產(chǎn)生大量的警告。
長遠(yuǎn)來看，當(dāng)然是要消除這些警告，但是短期來說呢？
即便是長期計劃，你也不能寫出完全沒有BUG的代碼，你也不能確保應(yīng)用將來永遠(yuǎn)不會打印出警告信息。
你能么？
你可以在警告打印到屏幕之前捕獲它們。
信號
Perl有一個叫做%SIG的內(nèi)建hash表，其中的鍵是操作系統(tǒng)信號的名字。對應(yīng)的值是函數(shù)（大多數(shù)是函數(shù)引用），這些函數(shù)會在特定的信號觸發(fā)時被調(diào)用。
除了系統(tǒng)提供的標(biāo)準(zhǔn)信號以外，Perl還添加了兩個內(nèi)部“信號”。其中一個是h__warn__ span="">，它在每次代碼調(diào)用warn()函數(shù)的時候觸發(fā)。另外一個是__DIE__，它在每次調(diào)用die()時觸發(fā)。
在本文中，我們會看到這些是怎樣影響警告信息的。
匿名函數(shù)
sub { }是匿名函數(shù)，也就是一個只有函數(shù)體而沒有名字的函數(shù)。（在這個例子中函數(shù)體也是空的，但是我希望你能明白我的意思。）
捕獲警告--不處理
如果添加如下代碼：
復(fù)制代碼 代碼如下:
local $SIG{__WARN__} = sub {
# 此處可以獲得警告信息
};
這實際上表示每次程序的某個地方產(chǎn)生了警告信息時，不做任何處理。基本上，這會隱藏所有的警告。
捕獲警告--并轉(zhuǎn)換成異常
You could also write: 你也可以寫成：
復(fù)制代碼 代碼如下:
local $SIG{__WARN__} = sub {
die;
};
這樣會在每次產(chǎn)生警告的時候調(diào)用die()，也就是把每個警告轉(zhuǎn)換成異常。
如果你想在異常中包含警告信息，可以這么寫：
復(fù)制代碼 代碼如下:
local $SIG{__WARN__} = sub {
my $message = shift;
die $message;
};
實際的警告信息會作為唯一的參數(shù)傳遞給匿名函數(shù)。
捕獲警告--并寫入日志
你可能想在中間做些其他事情：
過濾嘈雜的警告信息，留待后來分析：
復(fù)制代碼 代碼如下:
local $SIG{__WARN__} = sub {
my $message = shift;
logger($message);
};
這里我們假設(shè)logger()是你實現(xiàn)的寫日志函數(shù)。
寫日志
假設(shè)你的應(yīng)用程序已經(jīng)有日志機(jī)制。如果沒有的話，最好加上。即便你不能添加，你也需要操作系統(tǒng)的內(nèi)建日志機(jī)制。例如Linux的syslog，MS Windows的Event Logger，其它操作系統(tǒng)也有它們內(nèi)部的日志機(jī)制。
在本文的例子里，我們使用一個自制logger()函數(shù)來代表這個想法。
捕獲并寫日志的完整例子
復(fù)制代碼 代碼如下:
#!/usr/bin/perl
use strict;
use warnings;
local $SIG{__WARN__} = sub {
my $message = shift;
logger('warning', $message);
};
my $counter;
count();
print "$counter\n";
sub count {
$counter = $counter + 42;
}
sub logger {
my ($level, $msg) = @_;
if (open my $out, '>>', 'log.txt') {
chomp $msg;
print $out "$level - $msg\n";
}
}
上面的代碼會在log.txt文件中添加下面一行：
復(fù)制代碼 代碼如下:
Use of uninitialized value in addition (+) at code_with_warnings.pl line 14.
變量$counter和函數(shù)count()僅是產(chǎn)生警告示例的一部分。
警告處理函數(shù)中的警告信息
__WARN__在其處理函數(shù)執(zhí)行過程中是自動被禁用的。所以在警告處理函數(shù)執(zhí)行過程中產(chǎn)生的（新）警告信息不會導(dǎo)致無限循環(huán)。
你可以在perlvar文檔中了解到更多細(xì)節(jié)。
Avoid multiple warnings
需要注意的是重復(fù)的警告信息可能會充斥日志文件。我可以使用一個簡單的類似緩存的特性來減少重復(fù)警告信息的數(shù)量。
復(fù)制代碼 代碼如下:
#!/usr/bin/perl
use strict;
use warnings;
my %WARNS;
local $SIG{__WARN__} = sub {
my $message = shift;
return if $WARNS{$message}++;
logger('warning', $message);
};
my $counter;
count();
print "$counter\n";
$counter = undef;
count();
sub count {
$counter = $counter + 42;
}
sub logger {
my ($level, $msg) = @_;
if (open my $out, '>>', 'log.txt') {
chomp $msg;
print $out "$level - $msg\n";
}
}
可以看到，我們把$counter變量賦值成undef，然后再次調(diào)用count()函數(shù)來產(chǎn)生同樣的警告。
我們也把__WARN__的處理函數(shù)替換成一個稍微復(fù)雜的版本：
復(fù)制代碼 代碼如下:
my %WARNS;
local $SIG{__WARN__} = sub {
my $message = shift;
return if $WARNS{$message}++;
logger('warning', $message);
};
在調(diào)用logger之前，會檢查一下當(dāng)前字符串是否已經(jīng)在%WARNShash表中。如果沒有的話，會添加它并調(diào)用logger()。如果已經(jīng)有了，就調(diào)用return，并不二次記錄同樣的事件。
你可能回憶起我們在unique values in an array也使用了同樣的點(diǎn)子。
local是什么？
在上面所有的例子中，我使用local函數(shù)來局部化（警告處理）效果。嚴(yán)格來說，在這些例子中我們沒有必要這么做，因為假設(shè)這些代碼是主腳本的第一部分。這種情況下就無所謂了，畢竟是在全局作用域里面。
然而，最好是這么用。
local對于在模塊中限制（對警告）的改變是很重要的。特別是要發(fā)布的模塊。如果沒有局部化，會影響整個應(yīng)用程序。limit則會把影響限制在所在的閉合代碼塊里。
避免使用全局的%WARNS
如果你正在使用Perl 5.10或者更新的版本，你可以改寫一下代碼來替換掉全局變量%WARNS。要這么做的話，需在腳本的開頭使用use v5.10;，然后在匿名函數(shù)內(nèi)部使用state關(guān)鍵詞來聲明變量。
復(fù)制代碼 代碼如下:
#!/usr/bin/perl
use strict;
use warnings;
use v5.10;
local $SIG{__WARN__} = sub {
state %WARNS;
my $message = shift;
return if $WARNS{$message}++;
logger('warning', $message);
};
